zoxideはシェルでのディレクトリ移動の傾向を学習して、よく使うディレクトリへの移動を楽にするツールです。

https://github.com/ajeetdsouza/zoxide

しかし、行ったことのないディレクトリは候補に出ない。

そこで、使ったことないGitリポジトリへを移動先候補に加える方法として、よく使うディレクトリ+αへの移動を便利にするzoxideとghqの組み合わせという記事を書きました。

今回、もっと筋の良さそうな方法を思いついたので共有します。

Fishを例にしますが、AIを使えばBash版なりZsh版なりも簡単に作れるはず。

zoxide init --no-cmd fish | source # __zoxide_cd を定義させる

function zi
  begin
    # 利用頻度の高い移動先一覧
    zoxide query --list

    # 使いたくなるかもしれない移動先一覧
    ghq list -p
  end \
      | perl -ne 'print unless $seen{$_}++' \
      | fzf --layout=reverse --no-sort --height=~15 --query="$argv" \
      | read -l result
  and __zoxide_cd $result
end

使いたくなるかもしれない移動先一覧として、ghqコマンドで管理しているGitリポジトリ一覧を追加していますが、他にも色んな候補が考えられるかと思います！

• ホームディレクトリ配下のディレクトリとそのサブディレクトリ: find "$HOME" -maxdepth 2 -type d
• Neovimプラグイン一覧: find "$HOME/.local/share/nvim/lazy" -maxdepth 1 -type d

これらもそのまま行を足せばいいだけなので非常に拡張しやすいですね。

   begin
     # 利用頻度の高い移動先一覧
     zoxide query --list
 
     # 使いたくなるかもしれない移動先一覧
     ghq list -p
+    find "$HOME" -maxdepth 2 -type d
+    find "$HOME/.local/share/nvim/lazy" -maxdepth 1 -type d
   end \