変数を継承する

--inherit-variableオプションを使うと、指定した名前の変数のスナップショットを関数内で利用できます。やったね！

set --local x "hi"

function f --inherit-variable x
  echo "$x"
end

f
#> "hi"

スナップショットなので注意するべき点もあります。

まず、--inherit-variable利用前と同様に、関数外にある変数を更新することはできません。

set --local x "hi"

function f --inherit-variable x
  set x updated
end

f
echo $x
#> hi

次に関数定義の後に外側で変数を更新しても、関数内の変数は定義時点のままです。

set --local x "hi"

function f --inherit-variable x
  echo "$x"
end

set x updated

f
#> "hi"

どちらもスナップショットなので当然ではありますし、非常に安全性を重視した挙動かなと思います。

スコープのシャドイングを無効化する

すべての変数についてシャドイングが無効化されるため、注意して使うとよさそうです。

当然ですが、外側の変数を参照できます。

set --local x "hi"

function f --no-scope-shadowing
  echo "$x"
end

f

変数の継承と異なり、変数の更新も可能です。

set --local x "hi"

function f --no-scope-shadowing
  set x "updated"
end

f
echo $x
#> updated

ただし、シャドイングが有効な関数gの中で、シャドイングが無効な関数fを利用しても、gの外側の変数はスコープ外になるようです。このあたりも安全性重視ということでしょうか。

set --local x "hi"

function f --no-scope-shadowing
  set x "updated"
end

function g
  f
end

g
echo $x

グローバル変数を使う

もっとも素朴な方法ですね。help setには、任意の関数で使えることと、関数内で更新することができると書かれています。

当然参照できる。

set --global x "hi"

function f
  echo "$x"
end

f
#> hi

更新もできる。

set --global x "hi"

function f
  set x "updated"
end

f
echo $x
#> updated

ローカル環境変数を使う

環境変数の用途を考えると推奨されませんが、その性質上、関数内でも参照できます。

set --local --export x "hi"

function f
  echo "$x"
end

f
#> hi

ただしローカルなので、関数内で更新しても外側の変数は変わりません。

set --local --export x "hi"

function f
  set x "updated"
end

f
echo $x
#> "hi"

一方で、環境変数故に子プロセスに引き継がれる点は注意ですね。

set --local --export x "hi"

fish -c 'echo $x'

スクリプト内で使うと、スクリプトローカルな環境変数になるので、スクリプトをソースした場合もスクリプト内でのみ有効な変数になります。

set -l tempfile (mktemp)
echo '
set --local --export x "hi"

function f
  echo "$x"
end

f
' > $tempfile

source $tempfile
#> hi

echo $x

グローバル環境変数を使う

ローカル環境変数を関数内で参照できたとおり、グローバル環境変数も参照できます。

また関数内からの更新ができます。

スクリプト内で定義してソースした場合、スクリプトの外側でも有効な変数になります。

echo 'set --global --export x "hi"' | source -
echo $x
#> hi

ユニバーサル変数を使う

ユニバーサル変数は、Fishのプロセス間で共有される変数です。プロセスが終了しても残るので、使いどころには注意。こいつはなんでもアリですね。

# 別プロセスで`x`を定義
fish -c 'set -U x "hi"'

# 参照
function f
  echo $x
end

f

# fishを終了しても残るので消しとく
set --erase --universal x
echo $x